summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e396f7c8137bf45bef7299993ae30d1e945eed51 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
# Maintainer: Daniel Bermond < yahoo-com: danielbermond >

pkgname=xine-ui-hg
pkgver=0.99.10.r3326.12aa9b3c98fb
pkgrel=1
pkgdesc='A free video player for Unix (Mercurial version with all possible libs)'
arch=('i686' 'x86_64')
url='https://www.xine-project.org/'
license=('GPL2')
depends=('desktop-file-utils' 'hicolor-icon-theme' 'libcaca' 'libxft'
         'libxinerama' 'libxss' 'libxtst' 'libxv' 'libxxf86vm' 'lirc'
         'shared-mime-info' 'tar' 'xdg-utils' 'xine-lib')
makedepends=('libxt' 'mercurial')
provides=('xine-ui')
conflicts=('xine-ui')
source=("$pkgname"::'hg+http://hg.code.sf.net/p/xine/xine-ui')
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    
    # mercurial
    printf '%s.r%s.%s' "$(hg log --rev='branch(default) and tag()' --template='{tags}\n' | \
                              grep '^[0-9]*\(\.[0-9]*\(\.[0-9]*\(\.[0-9]*\)\?\)\?\)\?$'  | \
                              sort -Vr | \
                              head -n1)" \
                       "$(hg identify -n)" \
                       "$(hg identify -i)"
}

build() {
    cd "$pkgname"
    
    ./autogen.sh
    
    LIBS='-ldl' \
    ./configure \
        --prefix='/usr' \
        --mandir='/usr/share/man' \
        --enable-nls \
        --enable-shm \
        --enable-xinerama \
        --disable-aalibtest \
        --enable-mbs \
        --enable-xft \
        --enable-lirc \
        --enable-vdr-keys \
        --disable-nvtvsimple \
        --disable-debug \
        --with-x \
        --with-curl \
        --without-aalib \
        --with-caca \
        --with-fb \
        --with-tar
        
    make
}

package() {
    cd "$pkgname"
    
    make DESTDIR="$pkgdir" desktopdir='/usr/share/applications' install
}