summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 31bf29f7b1c1f54d4357a8f5111678f71c324d34 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Daniel Bermond < gmail-com: danielbermond >

pkgname=xine-ui-hg
pkgver=0.99.10.r3349.44f5b990a7ad
pkgrel=1
pkgdesc='A free video player for Unix (mercurial version)'
arch=('x86_64')
url='https://www.xine-project.org/'
license=('GPL')
depends=('xine-lib' 'curl' 'libxft' 'libxxf86vm' 'lirc' 'xdg-utils' 'libxss')
makedepends=('mercurial')
provides=('xine-ui')
conflicts=('xine-ui')
source=('hg+http://hg.code.sf.net/p/xine/xine-ui')
sha256sums=('SKIP')

pkgver() {
    cd xine-ui
    
    local _version
    _version="$(hg log --rev='branch(default) and tag()' --template='{tags}\n' |
                              grep '^[0-9]*\(\.[0-9]*\(\.[0-9]*\(\.[0-9]*\)\?\)\?\)\?$'  |
                              sort -Vr | head -n1)"
    printf '%s.r%s.%s' "$_version" "$(hg identify -n)" "$(hg identify -i)"
}

build() {
    cd xine-ui
    ./autogen.sh \
        --prefix='/usr' \
        --mandir='/usr/share/man' \
        --with-x \
        --enable-lirc \
        --without-aalib \
        --enable-debug
    make
}

package() {
    cd xine-ui
    make DESTDIR="$pkgdir" desktopdir='/usr/share/applications' install
}