summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5c212798a35d95f4969f8583e9499ca892904312 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=xiphos-git
pkgver=4.1.0.r72.g9e57333
pkgrel=1
epoch=1
pkgdesc='A Bible study tool for GTK3'
arch=('i686' 'x86_64')
url="http://xiphos.org"
license=('GPL2')
depends=('gconf'
         'gtkhtml4'
         'libbiblesync.so'
         'libgsf'
         'sword>=1.8.1'
         'webkit2gtk')
makedepends=('appstream-glib'
             'cmake'
             'docbook-utils'
             'git'
             'gnome-common'
             'gnome-doc-utils'
             'gtkmm'
             'intltool'
             'libxml2'
             'python')
provides=('gnomesword' "${pkgname%-git}")
conflicts=("${provides[@]}")
source=("git+https://github.com/crosswire/xiphos.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  git describe --tags --abbrev=7 HEAD | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${pkgname%-git}"
  cmake -S . -B build \
	-DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DGTKHTML=ON
  make -C build
}

package() {
  cd "${pkgname%-git}"
  make -C build DESTDIR="$pkgdir" install
}