summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 76a7246d779a73522c72d32d2ba4f0e3efc032ac (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=xiphos-git
pkgver=r4065
pkgrel=4
pkgdesc="A Bible study tool -- git version"
arch=('i686' 'x86_64')
url="http://xiphos.org"
license=('GPL')
depends=('dbus-glib' 'webkit2gtk' 'libgsf' 'sword>=1.8.1' 'gtkhtml4' 'biblesync-git')
makedepends=('gnome-common' 'gnome-doc-utils' 'intltool' 'git' 'python2' 'docbook-utils')
provides=('gnomesword' 'xiphos')
conflicts=('gnomesword' 'xiphos')
source=(git+https://github.com/crosswire/xiphos.git "http://deb.debian.org/debian/pool/main/x/xiphos/xiphos_4.1.0.1+dfsg1-1.debian.tar.xz")
sha512sums=('SKIP' '7438bc523b8a6d50a2474e43d9057081667436b8292eef9164a5478471e8dc3380f75a84c736ff95ce4ba29bc99588f1a48cf9dfbf5c7c431dd0d53374bfeeb6')

pkgver() {
  cd ${pkgname%-git}
  printf "r%s" $(git rev-list --count HEAD)
}

prepare () {
  cd ${pkgname%-git}
  sed -i 's+src/gnome2/+src/gtk/+g' "$srcdir"/debian/patches/0017*
  patch -Np1 < "$srcdir"/debian/patches/0016*
  patch -Np1 < "$srcdir"/debian/patches/0017*
}

build() {
  cd ${pkgname%-git}
  python2 ./waf --prefix=/usr --enable-webkit2 configure 
  python2 ./waf --prefix=/usr --enable-webkit2 build 
}

package() {
  cd ${pkgname%-git}
  python2 ./waf --destdir="$pkgdir" --no-post-install install 
}