summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fa08f057b47050a77005c906c32fd480f2d1f76a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=xiphos-git
pkgver=4.2.1.r5.gece84a4
pkgrel=1
epoch=1
pkgdesc='A Bible study tool for GTK3'
arch=('x86_64' 'i686')
url='http://xiphos.org'
license=('GPL2')
depends=('biblesync'
	 'dbus-glib'
         'gtkhtml4'
         'minizip'
         'sword'
         'webkit2gtk')
makedepends=('appstream-glib'
             'cmake'
             'docbook-utils'
             'git'
             'gnome-common'
             'gnome-doc-utils'
             'gtkmm'
             'intltool'
             'libffi'
             'libxml2'
             'python'
             'zlib'
             'zip')
provides=('gnomesword' "${pkgname%-git}")
conflicts=("${provides[@]}")
source=("git+https://github.com/crosswire/xiphos.git")
sha256sums=('SKIP')

pkgver() {
    cd "${pkgname%-git}"
    git describe --tags --abbrev=7 --match="[0-9]*" HEAD |
        sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${pkgname%-git}"
    cmake -S . -B build \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DGTKHTML=ON
    make -C build
}

package() {
    cd "${pkgname%-git}"
    make -C build DESTDIR="$pkgdir" install
}