blob: e35ff2082c93e6afd137974fe55809a318d46269 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Contributor: Łaurent ʘ❢Ŧ Ŧough <laurent dot fough at gmail dot com>
pkgname=xkcd-git
pkgver=r56.9c26c67
pkgrel=2
epoch=1
pkgdesc='CLI tool to fetch XKCD comics'
url='https://github.com/itsron717/XKCD'
depends=('python-click' 'python-pillow' 'python-requests')
makedepends=('git' 'python-setuptools' 'python-build' 'python-installer' 'python-wheel')
optdepends=(
'python-sh: to display the XKCD banner'
'lolcat: to display the XKCD banner'
'figlet: to display the XKCD banner'
)
license=('MIT')
arch=('any')
provides=("xkcd")
conflicts=("xkcd")
sha256sums=('SKIP')
source=("${pkgname}::git+${url}")
pkgver() {
cd ${pkgname}
printf "r%s.%s" $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}
build() {
cd ${pkgname}
python -m build --wheel --no-isolation
}
package() {
cd ${pkgname}
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|