PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: callmetango
# Contributor: artist <artist@artixlinux.org>
# Contributor: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: AndyRTR <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Alexander Baldeck <alexander@archlinux.org>

pkgname=xlibre-video-ati
_pkgname=xf86-video-ati
pkgver=25.0.1
pkgrel=5
epoch=1
pkgdesc="XLibre ati video driver"
arch=('x86_64')
url='https://github.com/X11Libre/xf86-video-ati'
license=('MIT')
depends=(
	'glibc'
	'libdrm'
	'libpciaccess'
	'mesa'
	'systemd-libs'
	'xlibre-xserver'
)
makedepends=(
	'systemd'
	'X-ABI-VIDEODRV_VERSION=28.0'
	'xlibre-xserver-devel'
)
provides=('xf86-video-ati')
conflicts=(
	'X-ABI-VIDEODRV_VERSION<28'
	'X-ABI-VIDEODRV_VERSION>=29'
	'xf86-video-ati'
)
groups=('xlibre-drivers')
source=("${url}/archive/refs/tags/xlibre-${_pkgname}-${pkgver}.tar.gz")
sha512sums=('e9899357107359dfd67137217daad3d85ba0a6a7a84ed93f3672a060df8e25eafd7ceffdf61cfc1a8bf28c0f3e62c4596eac5d53b7a0ad5dcb17c7475af9c84b')

build() {
	cd ${_pkgname}-xlibre-${_pkgname}-${pkgver}

#	CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common

	# Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
	# With them, module fail to load with undefined symbol.
	# See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
	export CFLAGS=${CFLAGS/-fno-plt}
	export CXXFLAGS=${CXXFLAGS/-fno-plt}
	export LDFLAGS=${LDFLAGS/-Wl,-z,now}

	NOCONFIGURE=1 ./autogen.sh
	./configure --prefix=/usr
	make
}

check() {
	cd ${_pkgname}-xlibre-${_pkgname}-${pkgver}
	make check
}

package() {
	cd ${_pkgname}-xlibre-${_pkgname}-${pkgver}

	make "DESTDIR=${pkgdir}" install
	install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
	install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}