blob: c7b80b282a7bc17fe318ada46781b867c0f95dc0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Stefen Wakefield <me@xstefen.dev>
_pkgname="xmap"
pkgname="$_pkgname-git"
pkgver=2.0.0.r15.gf30b823
pkgrel=2
pkgdesc="Fast Internet-wide IPv6 & IPv4 network scanner"
arch=('x86_64')
url="https://github.com/idealeer/xmap"
license=('Apache')
depends=('gmp' 'gengetopt' 'libpcap' 'json-c' 'libunistring')
makedepends=('cmake' 'flex' 'byacc' 'git')
conflicts=("$_pkgname")
provides=("$_pkgname")
_pkgsrc="$_pkgname"
source=("git+https://github.com/idealeer/xmap.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgsrc"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
sed -E 's|DESTINATION sbin|DESTINATION bin|' -i "$_pkgsrc/src/CMakeLists.txt"
}
build() {
local _cmake_options=(
-B build
-S "$_pkgsrc"
-DCMAKE_INSTALL_PREFIX='/usr'
-DENABLE_DEVELOPMENT=OFF
-DENABLE_LOG_TRACE=OFF
-Wno-dev
)
cmake "${_cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir:?}" cmake --install build
install -Dm644 "$_pkgsrc/LICENSE" -t "${pkgdir:?}/usr/share/licenses/$pkgname/"
}
|