summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0d1afeeecd706d05a612119530399ddc5298c7ef (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Johannes Wienke <languitar@semipol.de>

pkgname=xml-language-server-git
_xpkgname=xml-language-server
pkgver=r10.7a2bcbc
pkgrel=1
pkgdesc="Language server for XML files"
url="https://github.com/microclimate-devops/xml-language-server"
license=('EPL')
arch=('any')
depends=('java-environment' 'archlinux-java-run')
makedepends=('java-environment' 'maven')
conflicts=('xml-language-server')
provides=('xml-language-server')
source=("git+https://github.com/microclimate-devops/xml-language-server.git"
        "launcher.sh")
md5sums=('SKIP'
         '9d1121d6db14da3d7cfb74feb552e5e8')

pkgver() {
    cd "${srcdir}/${_xpkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "${srcdir}/${_xpkgname}/server/xml-server"
    mvn package
}

package() {
    install -Dm644 "${srcdir}/${_xpkgname}/server/xml-server/target/"*-server-all.jar \
                   "${pkgdir}/usr/share/java/${_xpkgname}/xml-language-server-all.jar"
    install -Dm755 "${srcdir}/launcher.sh" \
                   "${pkgdir}/usr/bin/${_xpkgname}"
}