PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Doug Johnson <dougvj@dougvj.net>

pkgname='xmrig-amd-git'
pkgver=r20.acd215f
pkgrel=1
pkgdesc='Monero cryptocurrency GPU miner (OpenCL for AMD)'
arch=('x86_64')
url='https://github.com/xmrig/xmrig-amd'
depends=('libuv' 'ocl-icd')
optdepends=('monero: wallet')
makedepends=('git' 'cmake' 'opencl-headers')
license=('GPL')
changelog=CHANGELOG.md
source=("git+https://github.com/xmrig/xmrig-amd.git");
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/xmrig-amd"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/xmrig-amd"

  # create build dir
  [ -d build ] || mkdir build

  # reset default donate level
  sed -i -e 's/constexpr const int kDonateLevel = 5;/constexpr const int kDonateLevel = 0;/g' src/donate.h
}

build() {
  cd "$srcdir/xmrig-amd/build"
  cmake -DWITH_HTTPD=OFF -DCMAKE_C_COMPILER=gcc-6 -DCMAKE_CXX_COMPILER=g++-6 ..
  make
}

package() {
  install -Dm775 "$srcdir/xmrig-amd/build/xmrig-amd" "$pkgdir/usr/bin/xmrig-amd"
  install -Dm644 "$srcdir/xmrig-amd/src/config.json" "$pkgdir/usr/share/doc/xmrig-amd/config.json.example"
  install -Dm644 "${srcdir}/xmrig-amd/README.md" "${pkgdir}/usr/share/doc/xmrig-amd/README.md"
  install -Dm644 "${srcdir}/xmrig-amd/CHANGELOG.md" "${pkgdir}/usr/share/doc/xmrig-amd/CHANGELOG.md"
}