PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Sven Hesse <drmccoy@drmccoy.de>

pkgname=xoreos-git
pkgver=0.0.6.r235.gf36b681
pkgrel=1
pkgdesc="A reimplementation of BioWare's Aurora engine"
arch=(x86_64)
url="https://github.com/xoreos/xoreos"
license=(GPL-3.0-or-later)
depends=(glibc gcc-libs zlib xz libxml2 boost-libs sdl2 freetype2 openal libmad libglvnd libvorbis faad2 xvidcore libvpx) #libogg
makedepends=(git boost)
provides=(xoreos)
conflicts=(xoreos)
source=("git+https://github.com/xoreos/xoreos.git")
sha256sums=('SKIP')

pkgver() {
  cd xoreos
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd xoreos
  ./autogen.sh
}

build() {
  cd xoreos
  ./configure --with-release=AUR --with-lto --prefix=/usr
  make
}

package() {
  cd xoreos
  make DESTDIR="$pkgdir/" install
}