summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 689dcfd3ac82dbeb2a9ad8b9a8e2a027ee0f444f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Johan Sk├Âld <johan@git.skold.cc>

_pkgname=xpad-noone
pkgname="${_pkgname}-git"
pkgver=r8.6970c40
pkgrel=1
pkgdesc='This is the original upstream xpad driver from the Linux kernel with support for Xbox One controllers removed.'
arch=('x86_64' 'aarch64')
url='https://github.com/medusalix/xpad-noone'
license=('GPL2')
depends=('dkms')
makedepends=('git')
conflicts=('xpad-dkms-git')
provides=('xpad-noone')
source=(
	"${_pkgname}::git+${url}.git"
	'modprobe.conf')
sha256sums=(
	'SKIP'
	'bdc54ef5b9728751f89f08039c69141f7515b9df723cbda1df0239c5109d249b')

pkgver() {
	cd "${srcdir}/${_pkgname}"
	printf "r%d.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

package() {
	install -d -m 755 "${pkgdir}/usr/src/${pkgname}-${pkgver}"
	find "${srcdir}/${_pkgname}" -maxdepth 1 -type f -exec install -D -m 644 {} "${pkgdir}/usr/src/${pkgname}-${pkgver}" \;
	install -D -m 644 "${srcdir}/modprobe.conf" "${pkgdir}/usr/lib/modprobe.d/xpad-noone-git-modprobe.conf"
}