blob: a64d84088fb074515f0fa10e73dffc77a76cc8f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Tau Tsao <realturner at gmail.com>
pkgname=xrdp-devel-git
_pkgname=xrdp
pkgver=0.9.12.r25.g6d7cce3d
pkgrel=1
pkgdesc="An open source remote desktop protocol (RDP) server - GIT version"
url="https://github.com/neutrinolabs/$_pkgname"
arch=('i686' 'x86_64' 'armv6h')
license=('Apache')
makedepends=('git' 'nasm')
depends=('tigervnc' 'libxrandr' 'lame' 'opus' 'fuse')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver%%.r*}-${pkgrel}")
backup=('etc/xrdp/sesman.ini' 'etc/xrdp/xrdp.ini')
install="${pkgname}.install"
source=("$pkgname::git+https://github.com/neutrinolabs/xrdp.git#branch=devel"
"arch-config.diff")
md5sums=('SKIP'
'5b0c7390d6380cc05cb76980426af9fc')
pkgver() {
cd $pkgname
printf "0.9.12.r%s.g%s" "$(git rev-list --count v0.9.12..HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $pkgname
patch -Np2 -b -z .orig < ../arch-config.diff
./bootstrap
}
build() {
cd $pkgname
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sbindir=/usr/bin \
--with-systemdsystemdunitdir=/usr/lib/systemd/system \
--enable-jpeg \
--enable-tjpeg \
--enable-fuse \
--enable-opus \
--enable-rfxcodec \
--enable-mp3lame \
--enable-pixman
# Fight unused direct deps
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make V=0
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
rm -f "$pkgdir"/etc/xrdp/rsakeys.ini
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
|