PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85

# Maintainer: Jat <chat@jat.email>

_pkgname='xrdp'
pkgname="$_pkgname-git"
pkgver=0.9.18.r492.g8535f8e0
pkgrel=1
pkgdesc='An open source remote desktop protocol (RDP) server. Git version, devel branch.'
url='https://github.com/neutrinolabs/xrdp'
arch=('i686' 'x86_64' 'armv6h' 'armv7l' 'aarch64')
license=('Apache')
provides=("$_pkgname")
conflicts=("$_pkgname")
makedepends=('nasm' 'cmocka')
depends=('libxrandr' 'fuse' 'libfdk-aac' 'ffmpeg' 'imlib2')
checkdepends=('check')
optdepends=('tigervnc' 'tightvnc' 'realvnc-vnc-server')
backup=('etc/xrdp/sesman.ini'
        'etc/xrdp/xrdp.ini'
        'etc/xrdp/cert.pem'
        'etc/xrdp/key.pem'
        'etc/xrdp/startwm.sh')
source=("git+$url#branch=devel"
        "arch-config.diff")
sha256sums=('SKIP'
            '332469b73e47d40554d52fcd6814908594306c80b4d4b2d6334476fbd4149ca8')
install="$pkgname.install"

pkgver() {
    cd "$srcdir/$_pkgname"

    git describe --long --tags | sed -E 's,^[^0-9]*,,;s,([0-9]*-g),r\1,;s,-,.,g'
}

prepare() {
    cd "$srcdir/$_pkgname"

    # https://github.com/neutrinolabs/xrdp/pull/2649
    sed -i '/^#include <check\.h>$/d' tests/libxrdp/test_libxrdp_main.c
    patch -p2 -i"$srcdir/arch-config.diff"
}

build() {
    cd "$srcdir/$_pkgname"

    ./bootstrap
    ./configure --prefix=/usr \
                --sysconfdir=/etc \
                --localstatedir=/var \
                --sbindir=/usr/bin \
                --with-systemdsystemunitdir=/usr/lib/systemd/system \
                --enable-jpeg \
                --enable-tjpeg \
                --enable-fuse \
                --enable-fdkaac \
                --enable-opus \
                --enable-rfxcodec \
                --enable-mp3lame \
                --enable-pixman \
                --enable-painter \
                --enable-vsock \
                --enable-ipv6 \
                --enable-pam-config=arch \
                --enable-rdpsndaudin \
                --with-imlib2

  # Fight unused direct deps
  sed -i -e "s| -shared | $LDFLAGS\0 |g" -e "s|    if test \"\$export_dynamic\" = yes && test -n \"\$export_dynamic_flag_spec\"; then|      func_append compile_command \" $LDFLAGS\"\n      func_append finalize_command \" $LDFLAGS\"\n\0|" libtool

  make
}

check () {
    cd "$srcdir/$_pkgname"

    make check
}

package() {
    cd "$srcdir/$_pkgname"

    make DESTDIR="$pkgdir" install
    install -Dm644 'COPYING' -t "$pkgdir/usr/share/licenses/$_pkgname"

    rm "$pkgdir/etc/xrdp/rsakeys.ini"
}