blob: 383ddcb24260d288586bb45840162599104dc160 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Tau Tsao <realturner at gmail.com>
pkgname=xrdp-git
pkgver=0.8.0.r1016.gcd8b5f00
pkgrel=1
epoch=1
pkgdesc="An open source remote desktop protocol (RDP) server - GIT version"
url="https://github.com/neutrinolabs/xrdp"
arch=('i686' 'x86_64' 'armv6h')
license=('Apache')
makedepends=('libpulse' 'fuse' 'git')
depends=('tigervnc' 'libxrandr')
optdepends=('libpulse: to use the pule audio module'
'fuse: to use the file clipboard module')
conflicts=('xrdp')
provides=('xrdp=0.8.0')
backup=('etc/xrdp/sesman.ini' 'etc/xrdp/xrdp.ini')
install=xrdp-git.install
source=("$pkgname::git+https://github.com/neutrinolabs/xrdp.git"
"arch-config.diff")
md5sums=('SKIP'
'6f938957f4b0ec3993258cdfa17b4621')
pkgver() {
cd $pkgname
printf "0.8.0.r%s.g%s" "$(git rev-list --count v0.8.0..HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $pkgname
patch -Np2 -b -z .orig <../arch-config.diff
./bootstrap
}
build() {
cd $pkgname
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sbindir=/usr/bin \
--with-systemdsystemdunitdir=/usr/lib/systemd/system \
--enable-jpeg \
--enable-simplesound \
--enable-fuse \
--enable-loadpulsemodules
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
|