blob: 7ce09f79dcacbd91c685952e6db38f6079906190 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Qingxu <me@linioi.com>
# Maintainer: k0kubun <takashikkbn@gmail.com>
pkgname=xremap-niri-bin
pkgdesc='Dynamic key remapper for X11 and Wayland (Niri Wayland Version)'
pkgver=0.15.9
pkgrel=1
provides=('xremap')
license=('MIT')
url='https://github.com/xremap/xremap'
arch=('x86_64' 'aarch64')
options=('!debug')
source=("LICENSE-$pkgver::https://raw.githubusercontent.com/xremap/xremap/v$pkgver/LICENSE")
sha256sums=('60365594c733128ba50f05de00c4a6f07fed0a6e8bbd93817f39ded3980f7343')
source_x86_64=("$pkgname-$pkgver-x86_64.zip::https://github.com/xremap/xremap/releases/download/v$pkgver/xremap-linux-x86_64-niri.zip")
sha256sums_x86_64=('8e6cf52697e2b07a55badc9b7ee9ee17391ef205dd076725f5b0f42fb762d7aa')
source_aarch64=("$pkgname-$pkgver-aarch64.zip::https://github.com/xremap/xremap/releases/download/v$pkgver/xremap-linux-aarch64-niri.zip")
sha256sums_aarch64=('347aaf7cbdd281a0aadeff43e4f0e4c79ebf0441b0f48d143cea2f73fb6e0305')
package() {
cd "$srcdir/"
./xremap --completions zsh > zsh_completions
./xremap --completions fish > fish_completions
./xremap --completions bash > bash_completions
install -Dm644 zsh_completions "${pkgdir}/usr/share/zsh/site-functions/_xremap"
install -Dm644 fish_completions "${pkgdir}/usr/share/fish/vendor_completions.d/xremap.fish"
install -Dm644 bash_completions "${pkgdir}/usr/share/bash-completion/completions/xremap"
install -Dm755 xremap "${pkgdir}/usr/bin/xremap"
install -Dm644 "LICENSE-$pkgver" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|