blob: ee227709bdbf46c0d8a133ac169c6b5462f67cf6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Alad Wenter <https://wiki.archlinux.org/index.php/Special:EmailUser/Alad>
# Contributor: Raymond Wagenmaker <raymondwagenmaker@gmail.com>
pkgname=xss-lock-git
pkgver=v0.3.0.4.g1e158fb
pkgrel=1
pkgdesc="Use external locker as X screen saver"
arch=(i686 x86_64)
url="https://bitbucket.org/raymonad/xss-lock"
license=('MIT')
depends=('xcb-util' 'systemd')
makedepends=('cmake' 'python-docutils' 'git')
optdepends=('bash-completion: for bash completion')
source=("$pkgname::git+https://bitbucket.org/raymonad/${pkgname%-git}.git"
'ignore-blank.patch')
md5sums=('SKIP'
'ccd244e49310672aa896587373b015f8')
provides=('xss-lock')
conflicts=('xss-lock')
pkgver() {
cd "$pkgname"
local ver="$(git describe --long)"
printf "%s" "${ver//-/.}"
}
prepare() {
cd "$pkgname"
patch -p0 < "$srcdir"/ignore-blank.patch
}
build() {
cd "$pkgname"
cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|