blob: 55f1b95df52846882c2ed84d429b570d1c66e673 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Amish <contact at via dot aur>
# Contributor: Iacopo Isimbaldi <isiachi@rhye.it>
# Contributor: Lubomir Krajcovic <lubomir.krajcovic(AT)gmail(DOT)com>
# Contributor: Vladimir Kutyavin <vlkut(AT)bk(DOT)ru>
pkgname=xtables-addons-dkms
pkgver=2.14
pkgrel=2
pkgdesc="Successor to patch-o-matic(-ng). Contains extensions that were not accepted in the main Xtables. DKMS flavor for kernels >= 3.7."
arch=('i686' 'x86_64')
license=('GPL2')
url="http://xtables-addons.sourceforge.net/"
depends=('dkms')
optdepends=('perl-text-csv-xs: required for building GeoIP database'
'unzip: required for building GeoIP database')
makedepends=()
conflicts=(xtables-addons xtables-addons-git xtables-addons-multikernel)
replaces=(xtables-addons xtables-addons-git xtables-addons-multikernel)
source=(dkms.conf
kernel-4.15.patch
https://sourceforge.net/projects/${pkgname%-dkms}/files/Xtables-addons/${pkgname%-dkms}-${pkgver}.tar.xz)
sha256sums=('c8989ec1ab0c3aaebf557fd19bc0391173a77fb5e7f8b3afc63d3f6593b3b5af'
'3cc007d8faa0025e0c2d748b3eb516ad31acbb6781e88efb0b6a7bf0b280db71'
'd215a9a8b8e66aae04b982fa2e1228e8a71e7dfe42320df99e34e5000cbdf152')
prepare() {
# go to builddir
cd "${srcdir}/xtables-addons-${pkgver}"
patch -p1 -i ../kernel-4.15.patch
# disable install-exec-hook (avoids useless calling of depmod -a at 'make install' stage)
sed -i 's/^install-exec-hook:$/dont-run:/' Makefile.am
# disable building of xt_ECHO (it's an example module, and it breaks the build)
sed -i 's/^build_ECHO=.*$/build_ECHO=n/' mconfig
}
build() {
cd "${srcdir}/xtables-addons-${pkgver}"
# build userspace parts
./autogen.sh
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--libdir=/usr/lib \
--mandir=/usr/share/man \
--docdir=/usr/share/doc \
--libexecdir=/usr/lib/iptables \
--with-xtlibdir=/usr/lib/iptables \
--without-kbuild
make
}
package() {
cd "${srcdir}/xtables-addons-${pkgver}"
# prepare dkms build tree
dkmsDst="${pkgdir}/usr/src/xtables-addons-${pkgver}"
mkdir -p "${dkmsDst}/"
cp -R . "${dkmsDst}/"
# prepare dkms config
cp "${srcdir}/dkms.conf" "${dkmsDst}/"
sed -i -e "s/@VERSION@/${pkgver}/" "${dkmsDst}/dkms.conf"
make DESTDIR="${pkgdir}" install
}
|