blob: 640320fc54bbe9cff99594ede6a3daa3d1ad1bfd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: tomKPZ <tomKPZ@gmail.com>
# Maintainer Original Package: Roger Duran <rogerduran@gmail.com>
# Maintainer Original Original Package: Conley Moorhous <conleymoorhous@gmail.com>
# Contributor: Dieter Plaetinck <dieter@plaetinck.be>
# Contributor: Thomas Jost <schnouki@schnouki.net>
pkgname=xtrace
pkgver=1.4.0
pkgrel=2
pkgdesc="trace communication between X client and server"
arch=('i686' 'x86_64')
license=('GPL')
depends=('glibc')
makedepends=('autoconf' 'automake' 'make')
optdepends=('xorg-xauth')
source=("http://deb.debian.org/debian/pool/main/x/xtrace/xtrace_${pkgver}.orig.tar.xz")
sha256sums=('8aef15eb42fa36c80dd8185d0a940321ba851328a3738ae897b4352e94d6331e')
build() {
cd "$srcdir/xtrace-${pkgver}"
autoreconf -i
./configure --prefix=/usr
make
}
check() {
cd "$srcdir/xtrace-${pkgver}"
make check
}
package() {
cd "$srcdir/xtrace-${pkgver}"
make DESTDIR="$pkgdir" install
# Rename executable to x11trace since glibc owns xtrace
mv "$pkgdir/usr/bin/xtrace" "$pkgdir/usr/bin/x11trace"
# Rename man page to x11trace since glibc owns xtrace
sed -i s/xtrace/x11trace/g "$pkgdir/usr/share/man/man1/xtrace.1"
mv "$pkgdir/usr/share/man/man1/xtrace.1" "$pkgdir/usr/share/man/man1/x11trace.1"
}
|