PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

pkgname=xwayland-satellite-hidpi-git
_pkgname=xwayland-satellite

pkgver=e7cc44e
pkgrel=1

pkgdesc="Xwayland satellite with HiDPI cursor scaling fixes"
arch=('x86_64')
url="https://github.com/ByDefolt/xwayland-satellite"
license=('MPL-2.0')

depends=(
  'glibc'
  'libgcc'
  'libxcb'
  'xcb-util-cursor'
  'xorg-xwayland'
)

makedepends=(
  'cargo'
  'clang'
  'git'
)

provides=(
  'xwayland-satellite'
)

conflicts=(
  'xwayland-satellite'
  'xwayland-satellite-git'
)

source=(
  "${_pkgname}::git+https://github.com/ByDefolt/xwayland-satellite.git#branch=x-cursor-changes"
)

sha256sums=('SKIP')

pkgver() {
  cd "$_pkgname"

  git describe --long --tags --always |
    sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$_pkgname"
  cargo fetch --locked
}

build() {
  cd "$_pkgname"

  cargo build \
    --frozen \
    --release \
    --features systemd
}

package() {
  cd "$_pkgname"

  install -Dm755 \
    target/release/xwayland-satellite \
    "$pkgdir/usr/bin/xwayland-satellite"

  install -Dm644 \
    LICENSE \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  install -Dm644 \
    resources/xwayland-satellite.service \
    "$pkgdir/usr/lib/systemd/user/xwayland-satellite.service"
}