blob: d98b7874825201834211d8ccea7f25083b554cc4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Felix Kauselmann <licorn at gmail dot com>
pkgname=(yacreader yacreaderlibraryserver)
pkgbase=yacreader
pkgver=9.9.1
_pkgext=2209046
pkgrel=1
pkgdesc="Comic reader for cross-platform reading and managing your digital comic collection."
arch=('i686' 'x86_64')
url="http://www.yacreader.com"
license=('GPL3')
depends=('qt5-base' 'qt5-multimedia' 'qt5-quickcontrols2' 'qt5-graphicaleffects' 'qt5-svg' 'hicolor-icon-theme' 'libunarr' 'libpdfium-nojs')
optdepends=(
'qt5-imageformats: Support for extra image formats'
'qrencode: YACReaderLibrary server info qr codes'
)
conflicts=('yacreader-bin' 'yacreaderlibraryserver-standalone' 'yacreader-git')
install='yacreader.install'
source=( "https://github.com/YACReader/yacreader/releases/download/${pkgver}/yacreader-${pkgver}.${_pkgext}-src.tar.xz")
sha256sums=('527dc611008324de74b0f1bd80f959b44d912a8ada385fca1e0ec99ba4636a06')
build() {
cd $srcdir/$pkgbase-$pkgver.${_pkgext}/
qmake-qt5 CONFIG+="pdfium server_bundled"
make
}
package_yacreader() {
cd $srcdir/$pkgbase-$pkgver.${_pkgext}/
make INSTALL_ROOT="$pkgdir" sub-YACReader-install_subtargets sub-YACReaderLibrary-install_subtargets
}
package_yacreaderlibraryserver() {
pkgdesc="Headless YACReaderLibrary server for use with YACReader for iOS."
install=yacreaderlibraryserver.install
cd $srcdir/$pkgbase-$pkgver.${_pkgext}/
make INSTALL_ROOT="$pkgdir" sub-YACReaderLibraryServer-install_subtargets
}
|