blob: af4b11ecd029810283584ad7b4cb97b0fa63566c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Icaro Perseo <icaroperseo[at]protonmail[dot]com>
pkgname=yaics
pkgver=0.5.r29.g1358c1a
pkgrel=1
pkgdesc="A simple GNU social client developed in Qt"
arch=('i686' 'x86_64')
conflicts=('yaics-git')
url="https://gitlab.com/stigatle/yaics/"
license=('GPL')
depends=('qt5-base' 'aspell' 'hicolor-icon-theme')
source=("${pkgname}::git+https://gitlab.com/stigatle/yaics.git")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
( set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd $pkgname
qmake yaics.pro
make
}
package() {
cd $pkgname
# Bin file
install -Dm755 yaics \
"$pkgdir/usr/bin/yaics"
# Desktop file
install -Dm644 yaics.desktop \
"$pkgdir/usr/share/applications/yaics.desktop"
# XML file
install -Dm644 yaics.appdata.xml \
"$pkgdir/usr/share/appdata/yaics.appdata.xml"
# Icons
install -Dm644 icons/16x16/yaics.png \
"$pkgdir/usr/share/icons/hicolor/16x16/apps/yaics.png"
install -Dm644 icons/32x32/yaics.png \
"$pkgdir/usr/share/icons/hicolor/32x32/apps/yaics.png"
install -Dm644 icons/48x48/yaics.png \
"$pkgdir/usr/share/icons/hicolor/48x48/apps/yaics.png"
install -Dm644 icons/64x64/yaics.png \
"$pkgdir/usr/share/icons/hicolor/64x64/apps/yaics.png"
install -Dm644 icons/80x80/yaics.png \
"$pkgdir/usr/share/icons/hicolor/80x80/apps/yaics.png"
install -Dm644 icons/yaics.xpm \
"$pkgdir/usr/share/pixmaps/yaics.xpm"
# Translations
install -d "$pkgdir/usr/share/yaics/translations"
install -Dm644 translations/* \
"$pkgdir/usr/share/${pkgname}/translations"
# Doc files
install -Dm644 ChangeLog \
"$pkgdir/usr/share/doc/${pkgname}/ChangeLog"
install -Dm644 AUTHORS \
"$pkgdir/usr/share/doc/${pkgname}/AUTHORS"
# Man files
install -Dm644 docs/yaics.1 \
"$pkgdir/usr/share/man/man1/yaics.1"
# License
install -Dm644 COPYING \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 cc=80 et:
|