PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=yajl-git
pkgver=2.1.0.r5.g5e3a785
pkgrel=2
pkgdesc="A fast streaming JSON parsing library in C"
arch=('i686' 'x86_64')
url="https://lloyd.github.io/yajl/"
license=('ISC')
depends=('glibc')
makedepends=('git' 'cmake')
provides=("yajl=$pkgver" 'libyajl.so')
conflicts=('yajl')
options=('staticlibs')
source=("git+https://github.com/lloyd/yajl.git")
sha256sums=('SKIP')


pkgver() {
  cd "yajl"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "yajl"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    ./
  make -C "_build"
}

check() {
  cd "yajl"

  make -C "_build" test test-api
}

package() {
  cd "yajl"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/yajl"
}