summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 634c8b511f89830bd47072df2205c9fde130befe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=yakuake-git
pkgver=v3.0.2.6.g87f7321
pkgrel=1
pkgdesc="A drop-down terminal emulator based on KDE Konsole technology. (GIT version)"
arch=('i686' 'x86_64')
url='https://www.kde.org/applications/system/yakuake'
license=('GPL')
depends=('knewstuff'
         'konsole'
         'kwayland'
         'hicolor-icon-theme'
         )
makedepends=('extra-cmake-modules'
             'git'
             'python'
             )
conflicts=('yakuake')
provides=('yakuake')
source=('git://anongit.kde.org/yakuake.git')
sha1sums=('SKIP')

pkgver() {
  cd yakuake
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../yakuake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}