blob: c00a59c0f22593b866ef64022f6e753cdba249f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: carstene1ns <url/mail: arch carsten-teibes de>
# Contributor: Frederic Bezies <fredbezies*gmail>
# Contributor: Ronan Rabouin <darkbaboon*gmail>
pkgname=yamagi-quake2
pkgver=5.22
pkgrel=1
pkgdesc="Enhanced Quake II engine optimized for modern systems"
url="http://www.yamagi.org/quake2/"
arch=('i686' 'x86_64')
license=('custom: Info-ZIP' 'GPL2')
depends=('libjpeg' 'sdl2' 'libxxf86vm' 'libvorbis')
optdepends=('quake2-demo: shareware data files'
'openal: alternative audio backend')
makedepends=('openal' 'mesa')
install=$pkgname.install
changelog=$pkgname.ChangeLog
source=("http://deponie.yamagi.org/quake2/quake2-$pkgver.tar.xz"
"$pkgname.desktop")
sha256sums=('1d7dc91b429cbb30e9777e4da445ffe38c85f2bfb6773f989ce2e6d33805d66f'
'984cba7e43033b5b2339879474854006b0340c55b6c20693df88e983e0f2daf2')
build() {
cd quake2-$pkgver
make WITH_SYSTEMWIDE=yes WITH_SYSTEMDIR=/usr/share/$pkgname
}
package() {
cd quake2-$pkgver
# client + server binaries
install -Dm755 release/quake2 "$pkgdir"/usr/bin/$pkgname
install -m755 release/q2ded "$pkgdir"/usr/bin/yamagi-q2ded
# game library
install -Dm644 release/baseq2/game.so "$pkgdir"/usr/share/$pkgname/baseq2/game.so
# doc
install -Dm644 README "$pkgdir"/usr/share/doc/$pkgname/README
install -m644 stuff/yq2.cfg "$pkgdir"/usr/share/doc/$pkgname
# desktop entry
install -Dm644 ../$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
install -Dm644 stuff/icon/Quake2.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
# licenses
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|