blob: a4f7c8cf6e01e80aba0635bfc523951e37b1191c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
pkgname=yamagi-quake2-xatrix-git
pkgver=2.05.r1.g99a032c
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Quake II - Mission Pack 1 ('The Reckoning') for yamagi-quake2 (development version)"
url="http://www.yamagi.org/quake2/"
license=('GPL' 'custom')
depends=('sh' 'yamagi-quake2')
makedepends=('cmake')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
install=${pkgname%-*}.install
source=(${pkgname%-*}::"git+https://github.com/yquake2/xatrix.git"
"${pkgname%-*}.sh"
"${pkgname%-*}.desktop")
sha256sums=('SKIP'
'7c60d4bd78a528f5cf08425cfdcb87dacf574d3912c44439e623e35f37fbc972'
'e65add2561c7dc4a14061e17a24436f768b69968fbc6fa06022acf9e17d80854')
pkgver() {
cd ${pkgname%-*}
git describe --long --tags | sed 's/^XATRIX_//;s/_/./;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
rm -rf build
mkdir -p build
}
build() {
cd build
cmake ../${pkgname%-*} -DCMAKE_BUILD_TYPE=Release
make
}
package() {
# game library
install -Dm644 build/Release/game.so "$pkgdir"/usr/lib/yamagi-quake2/xatrix/game.so
cd ${pkgname%-*}
# game launcher
install -Dm755 ../${pkgname%-*}.sh "$pkgdir"/usr/bin/${pkgname%-*}
# doc
install -Dm644 README "$pkgdir"/usr/share/doc/${pkgname%-*}/README
# desktop entry
install -Dm644 ../${pkgname%-*}.desktop "$pkgdir"/usr/share/applications/${pkgname%-*}.desktop
# license
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|