blob: ed9da0e369378e320286bf695c82f978fb6636cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Ben Brown <ben at demerara dot io>
# Contributor: PedroHLC <root@pedrohlc.com>
# Contributor: Moritz Poldrack <moritz at poldrack dot dev>
# Contributor: dnkl
_pkgname=yambar
pkgname="${_pkgname}-git"
pkgver=1.9.0.r41.g971361b
pkgrel=1
pkgdesc='Modular status panel for X11 and Wayland, inspired by polybar (source from git)'
arch=('x86_64' 'aarch64')
url='https://codeberg.org/dnkl/yambar'
license=('MIT')
makedepends=(
'git'
'meson'
'ninja'
'scdoc'
'tllist>=1.0.1'
'wayland-protocols'
'xorgproto')
depends=(
'alsa-lib'
'fcft>=3.0.0'
'json-c'
'libmpdclient'
'libpulse'
'libudev.so'
'libxcb'
'libyaml'
'pipewire'
'pixman'
'wayland'
'xcb-util'
'xcb-util-cursor'
'xcb-util-wm')
optdepends=('xcb-util-errors: better X error messages')
provides=("${_pkgname}=$pkgver")
conflicts=("${_pkgname}")
source=('git+https://codeberg.org/dnkl/yambar.git')
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags | sed 's/[^-]*-g/r&/;s/-/./g'
}
build() {
cd "${_pkgname}"
meson setup --buildtype=release --prefix=/usr \
--wrap-mode=nofallback \
-Db_lto=true \
-Dbackend-x11=enabled -Dbackend-wayland=enabled \
build
meson compile -C build
}
package() {
cd "${_pkgname}"
meson install -C build --destdir "${pkgdir}"
}
|