summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: de7177967495112f9ee7729a25943fd5ee154daa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
# Maintainer: Chris Billington <chrisjbillington@gmail.com>
# Contributor: Philip Goto <philip.goto@gmail.com>
# Contributor: drakkan <nicola.murino at gmail dot com>

pkgbase=yaru-git
pkgname=(yaru-sound-theme-git
         yaru-gtk-theme-git
         yaru-gtksourceview-theme-git
         yaru-gnome-shell-theme-git
         yaru-unity-theme-git
         yaru-metacity-theme-git
         yaru-icon-theme-git
         yaru-session-git)
pkgver=21.04.1.r14.gb01004d7c
pkgrel=1
pkgdesc="Yaru default ubuntu theme"
arch=(any)
url="https://github.com/ubuntu/yaru"
license=('GPL3')
makedepends=(meson sassc git)
options=('!strip' '!buildflags' 'staticlibs')
source=("git+https://github.com/ubuntu/yaru#branch=gnome-shell-40")
sha256sums=('SKIP')

pkgver() {
    cd yaru
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    arch-meson yaru build
    meson configure build -Dubuntu-unity=true
    ninja -C build
}

_delete_all_from_pkgdir_except() {
    if [[ "$1" != "sound-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/sounds
    fi
    if [[ "$1" != "gtk-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/themes/Yaru{,-light,-dark}/{gtk-*,index.theme}
    fi
    if [[ "$1" != "gtksourceview-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/gtksourceview-*
    fi
    if [[ "$1" != "gnome-shell-theme" ]]; then
        rm "${pkgdir}"/usr/share/themes/Yaru{,-light}/gnome-shell
        rm -r "${pkgdir}"/usr/share/gnome-shell/theme/Yaru{,-light}
    fi
    if [[ "$1" != "unity-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/themes/Yaru/unity
    fi
    if [[ "$1" != "metacity-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/themes/Yaru{,-light,-dark}/metacity-1
    fi
    if [[ "$1" != "icon-theme" ]]; then
        rm -r "${pkgdir}"/usr/share/icons
    fi
    if [[ "$1" != "session" ]]; then
        rm -r "${pkgdir}"/usr/share/{glib-2.0,xsessions,wayland-sessions}
        rm -r "${pkgdir}"/usr/share/gnome-shell/{extensions,modes}
    fi
    # Delete remaining empty directories:
    find "${pkgdir}" -type d -empty -delete
}

package_yaru-sound-theme-git() {
    pkgdesc="Yaru default ubuntu sound theme"
    provides=(yaru-sound-theme)
    conflicts=(yaru-sound-theme)

    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "sound-theme"
}

package_yaru-gtk-theme-git() {
    pkgdesc="Yaru default ubuntu gtk theme"  
    depends=(gtk3 gdk-pixbuf2 gtk-engine-murrine gnome-themes-extra)
    provides=(yaru-gtk-theme)
    conflicts=(yaru-gtk-theme)
    
    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "gtk-theme"
}

package_yaru-gtksourceview-theme-git() {
    pkgdesc="Yaru default ubuntu gtksourceview theme"  
    provides=(yaru-gtksourceview-theme)
    conflicts=(yaru-gtksourceview-theme)
    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "gtksourceview-theme"
}

package_yaru-gnome-shell-theme-git() {
    pkgdesc="Yaru default ubuntu gnome shell theme"  
    depends=(gnome-shell)
    provides=(yaru-gnome-shell-theme)
    conflicts=(yaru-gnome-shell-theme)
    
    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "gnome-shell-theme"
}

package_yaru-unity-theme-git() {
    pkgdesc="Yaru default ubuntu unity theme"  
    provides=(yaru-unity-theme)
    conflicts=(yaru-unity-theme)
    
    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "unity-theme"
}

package_yaru-metacity-theme-git() {
    pkgdesc="Yaru default ubuntu metacity theme"
    depends=(metacity)
    provides=(yaru-metacity-theme)
    conflicts=(yaru-metacity-theme)
    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "metacity-theme"
}

package_yaru-icon-theme-git() {
    pkgdesc="Yaru default ubuntu icon theme"  
    depends=(hicolor-icon-theme gtk-update-icon-cache librsvg humanity-icon-theme)
    provides=(yaru-icon-theme)
    conflicts=(yaru-icon-theme)

    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "icon-theme"
}

package_yaru-session-git() {
    pkgdesc="Yaru session"
    depends=(gnome-shell yaru-gnome-shell-theme)
    provides=(yaru-session)
    conflicts=(yaru-session)

    DESTDIR="$pkgdir" ninja -C build install 2>&1 >> install.log
    _delete_all_from_pkgdir_except "session"
}