PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

# Maintainer: Jguer <joaogg3@gmail.com>
pkgname=yay
pkgver=1.95
pkgrel=1
pkgdesc="Yet another yogurt. Pacman wrapper and AUR helper written in go."
arch=('i686' 'x86_64' 'arm')
url="https://github.com/Jguer/yay"
license=('GPL')
depends=(
  'sudo'
)
makedepends=(
	'go'
	'git'
)
conflicts=('yay-bin')
source=("yay::git://github.com/jguer/yay.git#branch=${BRANCH:-master}")
md5sums=('SKIP')

pkgver() {
	if [[ "$PKGVER" ]]; then
		echo "$PKGVER"
		return
	fi

	cd "$srcdir/$pkgname"
	local count=$(git rev-list --count HEAD)
	echo "1.${count}"
}

build() {
	cd "$srcdir/$pkgname"

	if [ -L "$srcdir/$pkgname" ]; then
		rm "$srcdir/$pkgname" -rf
		cp -r "$srcdir/.go/src/$pkgname/" "$srcdir/$pkgname"
	fi

	rm -rf "$srcdir/.go/src"

	mkdir -p "$srcdir/.go/src/github.com/jguer"

	export GOPATH="$srcdir/.go"

	cp -r "$srcdir/$pkgname" "$srcdir/.go/src/github.com/jguer/"

	cd "$srcdir/.go/src/github.com/jguer/$pkgname/cmd/yay"
	ln -sf "$srcdir/.go/src/github.com/jguer/$pkgname/cmd/yay" "$srcdir/$pkgname"

	git submodule update --init

  go get github.com/jguer/go-alpm
  go install -v \
		-gcflags "-trimpath $GOPATH/src" \
		-ldflags="-X main.version=$pkgver"
}

package() {
  #install executable
	find "$srcdir/.go/bin/" -type f -executable | while read filename; do
		install -DT "$filename" "$pkgdir/usr/bin/$(basename $filename)"
	done

	cd "$srcdir/.go/src/github.com/jguer/$pkgname"

  # Install GLP v3
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  # Install manpage
  install -Dm644 yay.8 "${pkgdir}/usr/share/man/man8/yay.8"

  # Install zsh completion
  install -Dm644 "zsh-completion" "${pkgdir}/usr/share/zsh/site-functions/_yay"

  # Install fish completion
  install -Dm644 "yay.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/yay.fish"

  # Install bash completion
  install -Dm644 "bash-completion" "${pkgdir}/usr/share/bash-completion/completions/yay"

}