blob: 76bf75b7fd7695775eaf61a5d42c5dff0bc79a88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Jguer <joaogg3@gmail.com>
pkgname=yay
pkgver=4.505
pkgrel=1
pkgdesc="Yet another yogurt. Pacman wrapper and AUR helper written in go."
arch=('i686' 'x86_64' 'armv7h' 'armv6h' 'aarch64')
url="https://github.com/Jguer/yay"
license=('GPL')
options=('!strip' '!emptydirs')
depends=(
'sudo'
)
makedepends=(
'git'
'go'
)
conflicts=('yay-bin' 'yay-git')
source=("https://github.com/Jguer/yay/archive/v${pkgver}.tar.gz")
sha1sums=('9918ce6ccb09a988b80eb38156f141f78a84add5')
prepare() {
export GOPATH="${srcdir}/.go"
export GOBIN="$GOPATH/bin"
mkdir -p "$GOPATH"
rm -rf "$GOPATH/src"
ln -sf "$srcdir/$pkgname-$pkgver/vendor" "$GOPATH/src"
}
build() {
export GOPATH="${srcdir}/.go"
export GOBIN="$GOPATH/bin"
cd "$srcdir/$pkgname-$pkgver"
go build -v -o ${pkgname} -ldflags "-s -w -X main.version=${pkgver}"
}
package() {
_output="${srcdir}/$pkgname-$pkgver"
install -Dm755 "${_output}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
# Install manpage
install -Dm644 "${_output}/yay.8" "${pkgdir}/usr/share/man/man8/yay.8"
# Install bash completion
install -Dm644 "${_output}/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/yay"
# Install zsh completion
install -Dm644 "${_output}/zsh-completion" "${pkgdir}/usr/share/zsh/site-functions/_yay"
# Install fish completion
install -Dm644 "${_output}/yay.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/yay.fish"
}
|