PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=ydotool
pkgver=0.2.0
pkgrel=1
pkgdesc="Generic command-line automation tool (no X!)"
arch=('x86_64')
depends=('libevdevplus' 'libuinputplus')
makedepends=('cmake' 'ninja' 'scdoc')
url="https://github.com/ReimuNotMoe/ydotool"
license=('AGPL3')
source=("$url/archive/v$pkgver.tar.gz"
        "$url/pull/96.patch"
        "80-uinput.rules")
sha256sums=('2311b003d2ff383f3348f17101f0df74f56616d530d66d0a014a52ba85a5dcf1'
            'f462b5f62306a5431e5aa39d1a8ba670300f7304a15cc720af5ded65193eaeda'
            'e092f5e7e474aec6c980c458046d0ff11b18750b53de2bf0a0aba1ca26e6d58e')

prepare() {
  cd "$pkgname-$pkgver"
  patch -sp1 -i ../96.patch
}

build() {
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_MANDIR=/usr/share/man \
    -DCMAKE_BUILD_TYPE=Release \
    -DCXXOPTS_ENABLE_INSTALL=OFF \
    -G Ninja \
    -S "$pkgname-$pkgver" -B build
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install

  install -Dm644 80-uinput.rules "$pkgdir/etc/udev/rules.d/80-uinput.rules"
}