PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Michael Lass <bevan@bi-co.net>
# Contributor: Sebastian Wolf < sebastian at melonkru dot de >
# Contributor: gost < gostrc at gmail dot com >
# Contributor: Mikolaj Pastuszko <deluminathor@gmail.com>
# Contributor: Stefan Seemayer < mail at semicolonsoftware dot de >
# Contributor: Gordin < 9ordin @t gmail dot com >
# Contributor: David Davis < davisd<a@t>davisd.com >

# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR

pkgname=yed
pkgver=3.24
pkgrel=1
epoch=1
pkgdesc='Very powerful graph editor written in java'
arch=('any')
url='http://www.yworks.com/en/products_yed_about.html'
license=('custom')
depends=('hicolor-icon-theme' 'java-runtime')
source=("https://www.yworks.com/resources/yed/demo/yEd-${pkgver}.zip"
        'yed.desktop'
        'yed'
        'graphml+xml-mime.xml')
sha256sums=('842909f6e4c15399b660f316056499e63e931f95ade43d850045d852d3128947'
            'cc6957cde6eba0d82ea523b0257f8c91fd1e330a1e2ad7d64890e48a2450aa98'
            '731b54c6e731704efe9847d78e2df474d59042452ace29d2786d76891295249e'
            'e751b69ed8a25faf46d4e4016ed8f1774abc88679067934a6081348e3d6fc332')

install=yed.install

package() {
  # Install jars
  install -Dm644 ${srcdir}/yed-${pkgver}/yed.jar ${pkgdir}/usr/share/java/yed/yed.jar
  install -dm755 ${pkgdir}/usr/share/java/yed/lib
  install -m644 ${srcdir}/yed-${pkgver}/lib/* ${pkgdir}/usr/share/java/yed/lib/

  # Install license
  install -Dm644 ${srcdir}/yed-${pkgver}/license.html ${pkgdir}/usr/share/licenses/yed/license.html

  # Install icons
  for n in $(ls ${srcdir}/yed-${pkgver}/icons/yed*.png | xargs -n1 basename | sed s/[^0-9]//g); do
      install -Dm644 ${srcdir}/yed-${pkgver}/icons/yed${n}.png ${pkgdir}/usr/share/icons/hicolor/${n}x${n}/apps/yed.png
  done

  # Install mime definition
  install -Dm644 ${srcdir}/graphml+xml-mime.xml ${pkgdir}/usr/share/mime/packages/graphml+xml-mime.xml

  # Install .desktop file
  install -Dm644 ${srcdir}/yed.desktop ${pkgdir}/usr/share/applications/yed.desktop

  # Install run script
  install -Dm755 ${srcdir}/yed ${pkgdir}/usr/bin/yed
}