PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Firas Zaidan <firas@zaidan.de>

pkgname=yeganesh
pkgdesc='dmenu with a sense of history (cabal sandbox build)'
pkgver=2.5
pkgrel=38

url='http://dmwit.com/yeganesh/'
license=('custom:BSD3')
arch=('i686' 'x86_64')
depends=('ghc-libs'
         'dmenu'
         'haskell-base'
         'haskell-containers'
         'haskell-directory'
         'haskell-filepath'
         'haskell-process'
         'haskell-strict'
         'haskell-time'
         'haskell-unix'
         'haskell-xdg-basedir')
makedepends=('ghc')
source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('3db8ec028b611992a4df251c6d14e6937179f41bff61560bc0095036e38952c125b5ce8663b8fd2f1e5a89da321d9195c850f83101f0910d86a666c335dc3403')

build() {
  cd ${pkgname}-${pkgver}

  runhaskell Setup configure -O \
    --enable-shared \
    --enable-executable-dynamic \
    --disable-library-vanilla \
    --enable-tests \
    --prefix=/usr \
    --dynlibdir=/usr/lib \
    --docdir="/usr/share/doc/${pkgname}" \
    --datasubdir="${pkgname}" \
    --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie' \
    -f-profiling
  runhaskell Setup build
}

package() {
  cd ${pkgname}-${pkgver}

  runhaskell Setup.lhs copy --destdir="${pkgdir}"

  # Requires pandoc, regex-posix, Pretty and cabal
  #runhaskell util/GenerateManpage.hs
  rm -r "${pkgdir}/usr/share/doc"
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}