blob: ea4446d50aeebd4bcf5706d06a28277c813950ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Trizen <echo dHJpemVuQHByb3Rvbm1haWwuY29tCg== | base64 -d>
# Contributor: Ivy Foster <iff@archlinux.org>
# Contributor: Alad Wenter <alad@mailbox.org>
# Contributor: Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: Daniel Wallace < danielwallace at gtmanfred dot com>
pkgname=youtube-viewer
pkgdesc='Command line utility for viewing YouTube videos'
url='https://github.com/trizen/youtube-viewer'
license=('Artistic2.0')
epoch=1
pkgver=3.10.7
pkgrel=1
depends=(perl perl-data-dump perl-file-sharedir perl-json perl-lwp-protocol-https perl-libwww perl-unicode-linebreak)
makedepends=(perl-module-build)
optdepends=(
'mpv: play videos with MPV'
'perl-file-sharedir: GTK GUI'
'perl-gtk3: GTK3 GUI'
'perl-json-xs: faster JSON to HASH conversion'
'perl-term-readline-gnu: better STDIN support'
'vlc: play videos with VLC'
'wget: download videos with wget'
'youtube-dl: play videos with encrypted signatures'
)
arch=(any)
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/trizen/youtube-viewer/archive/$pkgver.tar.gz"
"https://github.com/trizen/youtube-viewer/releases/download/$pkgver/youtube-viewer-$pkgver.tar.gz.asc"
)
install=youtube-viewer.install
validpgpkeys=(ABB8BBAA2E279767774149B7D0A443C703A3A056)
# sums provided by packager makepkg -g
b2sums=('b4127851bc13f18a38c09a5c6c2d2398104b8b2201e8b6536ec252bce1b666589de0330b8ff599da141ee2c5ab2686dabbb7045222fd74f00d129e1b4d2060c2'
'SKIP')
build() {
cd "youtube-viewer-$pkgver"
perl Build.PL --installdirs vendor --gtk
}
check() {
cd "youtube-viewer-$pkgver"
./Build test
}
package() {
cd "youtube-viewer-$pkgver"
./Build install --destdir "$pkgdir"
rm -r "$pkgdir/usr/lib"
install -D -m 644 README.md "$pkgdir/usr/share/doc/youtube-viewer/README.md"
mkdir -p "$pkgdir/usr/share/applications" "$pkgdir/usr/share/pixmaps"
mv "$pkgdir/usr/share/perl5/vendor_perl/auto/share/dist/WWW-YoutubeViewer/gtk-youtube-viewer.desktop" \
"$pkgdir/usr/share/applications/gtk-youtube-viewer.desktop"
cp "$pkgdir/usr/share/perl5/vendor_perl/auto/share/dist/WWW-YoutubeViewer/icons/gtk-youtube-viewer.png" \
"$pkgdir/usr/share/pixmaps/gtk-youtube-viewer.png"
}
|