blob: d6bf8516ff30d2afb034ff4435ab93343cee6969 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Trizen <echo dHJpemVuQHByb3Rvbm1haWwuY29tCg== | base64 -d>
_pkgname=youtube-viewer
pkgname=youtube-viewer-git
pkgver=3.11.1.r0.gbd053b0
pkgrel=1
pkgdesc="A lightweight YouTube client for Linux"
arch=('any')
url="https://github.com/trizen/youtube-viewer"
license=('Artistic2.0')
makedepends=('git')
provides=('youtube-viewer')
conflicts=('youtube-viewer')
depends=('perl' 'perl-data-dump' 'perl-json' 'perl-lwp-protocol-https' 'perl-libwww' 'perl-unicode-linebreak')
optdepends=(
'ffmpeg: conversions and MKV merging'
'perl-json-xs: faster JSON parsing'
'perl-lwp-useragent-cached: local cache support'
'perl-term-readline-gnu: better STDIN support (+history)'
'mpv: play videos with MPV (recommended)'
'vlc: play videos with VLC'
'wget: download videos with wget'
'youtube-dl: play videos with encrypted signatures'
)
source=('git+https://github.com/trizen/youtube-viewer.git')
sha512sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
( export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor INSTALLVENDORSCRIPT=/usr/bin DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "$_pkgname"
/usr/bin/perl Makefile.PL
make
)
}
check() {
cd "$_pkgname"
( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
make test
)
}
package() {
cd "$_pkgname"
make install
rm -r "$pkgdir/usr/lib"
find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}
|