blob: 3034a1dc75365b534977cf3137fa0214e0843cc9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Trizen <echo dHJpemVuQHByb3Rvbm1haWwuY29tCg== | base64 -d>
_pkgname=youtube-viewer
pkgname=youtube-viewer-git
pkgver=3.5.4
pkgrel=1
pkgdesc="A command line utility for searching and streaming videos from YouTube."
arch=('any')
url="https://github.com/trizen/youtube-viewer"
license=('Artistic2.0')
makedepends=('git')
provides=('youtube-viewer')
conflicts=('youtube-viewer')
depends=('perl>=5.16.0' 'perl-data-dump' 'perl-json' 'perl-lwp-protocol-https' 'perl-libwww')
optdepends=(
'perl-json-xs: faster JSON to HASH conversion'
'perl-lwp-useragent-cached: local cache support'
'perl-unicode-linebreak: for printing results in a fixed-width format (-W)'
'perl-term-readline-gnu: for better STDIN support (+history)'
'youtube-dl: for playing videos with encrypted signatures'
'wget: for downloading videos with wget'
'mplayer: for playing videos with MPlayer'
'vlc: for playing videos with VLC'
'mpv: for playing videos with MPV (recommended)'
'ffmpeg: for conversions and MKV merging'
)
source=('git+https://github.com/trizen/youtube-viewer.git')
md5sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --always | sed -e 's|-|.|g'
}
build() {
( export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor INSTALLVENDORSCRIPT=/usr/bin DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "$_pkgname"
/usr/bin/perl Makefile.PL
make
)
}
check() {
cd "$_pkgname"
( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
make test
)
}
package() {
cd "$_pkgname"
make install
rm -r "$pkgdir/usr/lib"
find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}
|