summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5d5e0b07467bb8ef8c7dccb3431361d80d8d66fd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Ryan Wu <ryanwusd at gmail dot com>

pkgname=yt-collate
_name=${pkgname//-/_}
pkgver=0.0.5
pkgrel=2
pkgdesc="Efficient, well-rounded YouTube Music TUI client"
arch=('any')
url="https://github.com/indigo0445/yt-collate"
license=('MIT')
depends=(
  python
  python-textual
  python-ytmusicapi
  python-pydantic
  python-pydantic-settings
  python-pypresence
  mpv
  yt-dlp
  nodejs
  ffmpeg
)
makedepends=(
  python-build
  python-installer
  python-setuptools
  python-wheel
)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_name-$pkgver.tar.gz")
sha256sums=('041d7d4c98766a6ccdf2c4977d191c33f08150aeb7e0866205568f11e864bcd0')

build() {
  cd "$_name-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$_name-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}