blob: b0c92c90ad5004ef0cc61ef172a2cd3f889e8394 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Peter <peternaame@gmail.com>
pkgname=ytm-player-git
pkgver=2.0.0
pkgrel=1
pkgdesc="A full-featured YouTube Music TUI client with vim-style navigation"
arch=('any')
url="https://ytm-player.com"
license=('MIT')
depends=(
'mpv'
'python'
'python-aiosqlite'
'python-click'
'python-dbus-fast>=5'
'python-mpv'
'python-packaging'
'python-pillow'
'python-textual>=7.0'
'python-textual<9.0'
'python-ytmusicapi'
'yt-dlp'
)
makedepends=('git' 'python-build' 'python-installer' 'python-hatchling')
optdepends=(
'python-anyascii: lyrics transliteration to ASCII'
'python-pylast: Last.fm scrobbling'
'python-pypresence: Discord Rich Presence'
'python-spotipy: Spotify playlist import (AUR)'
'python-thefuzz: Spotify import fuzzy matching (AUR)'
)
provides=('ytm-player')
conflicts=('ytm-player')
# url is the package homepage (AUR display). source is the build fetch location.
# They intentionally differ. Do not collapse them via "git+${url}.git".
source=("git+https://github.com/peternaame-boop/ytm-player.git")
sha256sums=('SKIP')
pkgver() {
cd ytm-player
git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd ytm-player
python -m build --wheel --no-isolation
}
package() {
cd ytm-player
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|