blob: 1d1d60c64d4d4684dad5e47cbd45bc1f61c6b2c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Trivernis <trivernis@gmail.com>
# Maintainer: Jean Lucas <jean@4ray.co>
pkgname=yuna
pkgver=1.4.17
pkgrel=1
pkgdesc='Anime player & list manager integrating AniList, Simkl, Crunchyroll, and Hidive'
arch=(x86_64)
url=https://yuna.moe
license=(AGPL3)
depends=('gtk3' 'libxss' 'nss')
makedepends=('nodejs-lts-erbium' 'yarn' 'node-gyp' 'python2')
options=(!strip)
source=($pkgname-$pkgver.tar.gz::https://github.com/BeeeQueue/yuna/archive/v$pkgver.tar.gz
electron-builder.patch
yuna.desktop)
sha512sums=('fdcb92814ea93c6edec170d7405c3e0b4437ea52f270e53bdfd290416326cee51c902610fabcfb5388ac220a76ca9fa8225fdba195a4bf0a56685560f2e70ada'
'893065948029906084e5a7f94982a666fc553b294d2a423dc1642d6c67b1755e1f6ac0304adf726ff26c6b1ce74fbb8fc76a8bd129527abb3d7529ca59ebf643'
'1853e9eac6b6a3b0734711d0803135902f118168603c795543de3296928293773d2be7a2aef05b045b737305d6cb50273e01843544de53d9caf06d0b4dc3e982')
prepare() {
cd $pkgname-$pkgver
# Tell Electron Builder to only target a directory build
patch -Np0 < ../electron-builder.patch
# Remove GIT_TAG const since this is an archive download
# Remove Sentry source maps config since we don't have project info
sed -r '6,13d;71,91d' -i vue.config.js
}
build() {
cd $pkgname-$pkgver
yarn
yarn get-schema
yarn build
}
package() {
cd yuna-$pkgver
install -d "$pkgdir"/usr/{lib,bin}
cp -a dist_electron/linux-unpacked "$pkgdir"/usr/lib/yuna
ln -s /usr/lib/yuna/yuna "$pkgdir"/usr/bin
install -Dm 644 ../yuna.desktop -t "$pkgdir"/usr/share/applications
for i in 64 128 256 512; do
install -Dm 644 public/icons/${i}x${i}.png \
"$pkgdir"/usr/share/icons/hicolor/${i}x${i}/apps/yuna.png
done
}
|