blob: a0d03e688185eefdbf9a97740e85aea0cb29d175 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Maintainer: Brendan Szymanski <brendan.szymanski1@gmail.com>
_pkgname=yuzu
pkgname=$_pkgname-canary-git
pkgver=r9608.894a6812b
pkgrel=1
pkgdesc="An experimental open-source Nintendo Switch emulator/debugger"
arch=('i686' 'x86_64')
url="https://github.com/yuzu-emu/yuzu-canary"
license=('GPL2')
depends=('shared-mime-info' 'desktop-file-utils' 'sdl2' 'qt5-base' 'qt5-multimedia' 'qt5-tools' 'libxkbcommon-x11')
makedepends=('git' 'cmake' 'python')
optdepends=('qt5-wayland: for Wayland support')
source=("$_pkgname::git+https://github.com/yuzu-emu/yuzu-canary"
'git+https://github.com/svn2github/inih'
'git+https://github.com/yuzu-emu/ext-boost'
'git+https://github.com/philsquared/Catch'
'git+https://github.com/kinetiknz/cubeb'
'git+https://github.com/MerryMage/dynarmic'
'git+https://github.com/herumi/xbyak'
'git+https://github.com/fmtlib/fmt'
'git+https://github.com/lz4/lz4'
'git+https://github.com/yuzu-emu/unicorn'
'git+https://github.com/DarkLordZach/mbedtls'
'git+https://github.com/ogniK5377/opus'
'git+https://github.com/citra-emu/ext-soundtouch'
'git+https://github.com/citra-emu/ext-libressl-portable'
'git+https://github.com/discordapp/discord-rpc.git'
# cubeb dependencies
'git+https://github.com/google/googletest'
'git+https://github.com/arsenm/sanitizers-cmake')
md5sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgname"
git submodule init
git config submodule.inih.url "$srcdir/inih"
git config submodule.boost.url "$srcdir/ext-boost"
git config submodule.catch.url "$srcdir/Catch"
git config submodule.cubeb.url "$srcdir/cubeb"
git config submodule.dynarmic.url "$srcdir/dynarmic"
git config submodule.xbyak.url "$srcdir/xbyak"
git config submodule.fmt.url "$srcdir/fmt"
git config submodule.lz4.url "$srcdir/lz4"
git config submodule.unicorn.url "$srcdir/unicorn"
git config submodule.mbedtls.url "$srcdir/mbedtls"
git config submodule.opus.url "$srcdir/opus"
git config submodule.soundtouch.url "$srcdir/ext-soundtouch"
git config submodule.libressl.url "$srcdir/ext-libressl-portable"
git config submodule.discord-rpc.url "$srcdir/discord-rpc"
git submodule update --init --recursive
cd externals/cubeb
git config submodule.googletest.url "$srcdir/googletest"
git config submodule.cmake/sanitizers-cmake.url "$srcdir/sanitizers-cmake"
git submodule update --init --recursive
cd ../dynarmic
git config submodule.externals/fmt.url "$srcdir/fmt"
git config submodule.externals/xbyak.url "$srcdir/xbyak"
git submodule update --init --recursive
}
build() {
# Trick the compiler into thinking we're building from a continuous
# integration tool so the build number is correctly shown in the title
cd "$srcdir/$_pkgname"
export CI=true
export TRAVIS=true
export TRAVIS_REPO_SLUG=yuzu-emu/yuzu-canary
export TRAVIS_TAG=$(git describe --tags)
mkdir -p build
cd build
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DYUZU_USE_BUNDLED_UNICORN=ON \
-DYUZU_ENABLE_COMPATIBILITY_REPORTING=ON \
-DENABLE_COMPATIBILITY_LIST_DOWNLOAD=ON \
-DUSE_DISCORD_PRESENCE=ON
make
}
check() {
cd "$srcdir/$_pkgname/build"
make test
}
package() {
cd "$srcdir/$_pkgname/build"
make DESTDIR="$pkgdir/" install
}
|