PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Tony Lambiris <tony@libpcap.net>

pkgname=zafiro-icon-theme-git
pkgver=1.3.r40.geb4691f
pkgrel=1
pkgdesc="Icon pack flat with light colors"
arch=('any')
url="https://github.com/zayronxio/Zafiro-icons"
license=('GPL3')
options=(!strip)
makedepends=('git')
conflicts=('zafiro-icon-theme')
provides=('zafiro-icon-theme')
source=("${pkgname}::git+https://github.com/zayronxio/Zafiro-icons")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"

	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

package() {
	cd "${srcdir}/${pkgname}"

	msg "Checking filenames for any non-ascii characters..."
	while read file; do
		msg2 "$(mv -vf "$file" "$(tr -cd '\000-\177' <<<$file)")"
	done < <( find . -type f | grep -P "[^\x00-\x7F|\x80-\xFF]" )

	install -dm755 "${pkgdir}/usr/share/icons/Zafiro"
	cp -a * "${pkgdir}/usr/share/icons/Zafiro"

	install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}