blob: 14d43ab326acffcba8d66c63b5524468c5c55446 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
pkgname=whatsapp-nativefier
pkgver=0.3.2846
pkgrel=1
pkgdesc="WhatsApp desktop built with nativefier (electron)"
arch=("armv7l" "i686" "x86_64")
url="https://web.${pkgname%-nativefier}.com"
license=("custom")
depends=("gtk3" "libxss" "nss")
makedepends=("imagemagick" "nodejs-nativefier")
source=(
"${pkgname}.png"
"${pkgname}.desktop"
"${pkgname}-inject.js")
sha256sums=(
"3899581abcfed9b40b7208bbbca8bdbfe3ae9655980dbf55f04dec9cb3309f27"
"a4ea20639ea570d2f9ec6040b8873136fa507e0aa2341fd98aad25aa6bb66e2e"
"e1051cf02ab194073370cce0f0e8226e58df03e8e55fa310cfa998b17ff1a52e"
)
build() {
cd "${srcdir}"
nativefier \
--name "WhatsApp" \
--icon "${pkgname}.png" \
--width "800px" \
--height "600px" \
--inject "${pkgname}-inject.js" \
--verbose \
--single-instance \
--tray \
"https://web.${pkgname%-nativefier}.com"
}
package() {
install -dm755 "${pkgdir}/"{opt,usr/{bin,share/{applications,licenses/${pkgname}}}}
cp -rL "${srcdir}/whats-app-linux-"* "${pkgdir}/opt/${pkgname}"
ln -s "/opt/${pkgname}/whats-app" "${pkgdir}/usr/bin/${pkgname}"
install -Dm755 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm755 "${pkgdir}/opt/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
for _size in "192x192" "128x128" "96x96" "64x64" "48x48" "32x32" "24x24" "22x22" "20x20" "16x16" "8x8"
do
install -dm755 "${pkgdir}/usr/share/icons/hicolor/${_size}/apps"
convert "${srcdir}/${pkgname}.png" -resize "${_size}" "${pkgdir}/usr/share/icons/hicolor/${_size}/apps/${pkgname}.png"
done
}
|