blob: b99b760a1d53a5104b279ad03009c4866c289b96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: a821
# Contributor: Moritz Lipp <mlq@pwmt.org>
pkgname=zathura-git
pkgver=2026.07.08.r6.gedc0ca7e
pkgrel=1
pkgdesc="Minimalistic document viewer"
arch=('x86_64')
url="https://pwmt.org/projects/zathura"
license=('Zlib')
depends=('cairo' 'file' 'girara-git' 'glibc' 'glib2' 'gtk4' 'json-glib' 'libseccomp' 'libsynctex' 'sqlite')
makedepends=('git' 'meson' 'ninja' 'python-sphinx')
conflicts=('zathura')
provides=('zathura')
source=("$pkgname::git+https://github.com/pwmt/zathura.git#branch=develop")
md5sums=('SKIP')
optdepends=(
'zathura-djvu-git: DjVu support'
'zathura-pdf-poppler-git: PDF support using Poppler'
'zathura-pdf-mupdf-git: PDF support using MuPDF'
'zathura-ps-git: PostSctipt support'
'zathura-cb-git: Comic book support'
)
pkgver() {
cd "$pkgname"
git describe --tags --long | sed 's/-/.r/;s/-/./g'
}
build() {
cd "$pkgname"
arch-meson build -Dtests-x11=disabled -Dtests-wayland=disabled
ninja -C build
}
package() {
cd "$pkgname"
DESTDIR="$pkgdir/" ninja -C build install
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim:set ts=2 sw=2 et:
|