summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1a62abe1d71588e23665fbf44f4746760f943a18 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Oleg Shparber <oleg@zealdocs.org>

_appname=zeal

pkgname=${_appname}-git
pkgver=0.6.0.r0.gbae9a49
pkgrel=1
pkgdesc="A simple documentation browser"
arch=('i686' 'x86_64')
url="https://zealdocs.org/"
license=('GPL3')
depends=('desktop-file-utils' 'hicolor-icon-theme'
         'libarchive' 'qt5-webkit' 'qt5-x11extras'
         'sqlite' 'xcb-util-keysyms' 'xdg-utils')
makedepends=('cmake' 'extra-cmake-modules' 'git')
conflicts=(${_appname})
source=("${_appname}::git+https://github.com/zealdocs/${_appname}")
sha1sums=('SKIP')

pkgver() {
    cd ${_appname}
    git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    mkdir -p build
    cd build
    cmake -DCMAKE_INSTALL_PREFIX=/usr ${srcdir}/${_appname}
    make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
}