blob: 7b19aa301d92c2c409b21f3f8afbb359c20807a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Jakob Gahde <j5lx@fmail.co.uk>
pkgname=zeroskip-git
pkgver=r354.1945d64
pkgrel=1
pkgdesc="A key-value database library"
arch=('x86_64')
url="https://github.com/cyrusimap/zeroskip"
license=('MIT')
depends=('zlib' 'libutil-linux')
makedepends=('git' 'check')
provides=("zeroskip=${pkgver}")
conflicts=("zeroskip")
source=("git+https://github.com/cyrusimap/zeroskip.git")
sha512sums=('SKIP')
pkgver() {
cd "${srcdir}/zeroskip"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/zeroskip"
autoreconf -i
}
build() {
cd "${srcdir}/zeroskip"
./configure --prefix=/usr
make
}
check() {
cd "${srcdir}/zeroskip"
make check
}
package() {
cd "${srcdir}/zeroskip"
make install DESTDIR="${pkgdir}"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|