blob: a80baa1f70b4b74364229974b82b2965ae74a3d0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Iacopo Isimbaldi <isiachi@rhye.it>
pkgbase="zfs-dkms-git"
pkgname=("zfs-dkms-git" "zfs-utils-dkms-git")
pkgver=0.7.0_r481_gbc5f51c5d
pkgrel=1
license=('CDDL')
makedepends=("git" "spl-dkms-git" "python2")
arch=("i686" "x86_64")
url="http://zfsonlinux.org/"
source=("git+https://github.com/zfsonlinux/zfs.git"
"zfs-utils.bash-completion-r1"
"zfs-utils.initcpio.install"
"zfs-utils.initcpio.hook")
sha256sums=('SKIP'
'b60214f70ffffb62ffe489cbfabd2e069d14ed2a391fac0e36f914238394b540'
'e33adabbe3f2f4866802c9d63c7810c7a42b4df2288d0cdd23376519b15b36e4'
'290b18f538badce2eedd4ac4926a579535ec6c887436569fa6ff3685b55776bf')
pkgver() {
cd "${srcdir}/zfs"
git describe --match "zfs-*" --long --tags | sed -e 's|zfs-||' -e 's|-\([0-9]*-g\)|-r\1|' -e 's|[-: ]|_|g'
}
build() {
cd "${srcdir}/zfs"
./autogen.sh
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--with-mounthelperdir=/usr/bin \
--libdir=/usr/lib \
--datadir=/usr/share \
--includedir=/usr/include \
--with-udevdir=/usr/lib/udev \
--libexecdir=/usr/lib/zfs \
--with-config=user \
--enable-systemd \
--enable-pyzfs
make
}
package_zfs-dkms-git() {
pkgdesc="Kernel modules for the Zettabyte File System. (Git version)"
depends=("spl-dkms-git" "zfs-utils-dkms-git=${pkgver}-${pkgrel}" "dkms")
provides=("zfs")
conflicts=("zfs-git" "zfs-lts" "zfs-dkms")
dkmsdir="${pkgdir}/usr/src/zfs-${pkgver%%_*}"
install -d "${dkmsdir}"
cp -a ${srcdir}/zfs/. ${dkmsdir}
cd "${dkmsdir}"
make clean
make distclean
find . -name ".git*" -print0 | xargs -0 rm -fr --
scripts/dkms.mkconf -v ${pkgver%%_*} -f dkms.conf -n zfs
chmod g-w,o-w -R .
}
package_zfs-utils-dkms-git() {
pkgdesc="Kernel module support files for the Zettabyte File System. (Git version)"
depends=("python2")
provides=("zfs-utils")
conflicts=("zfs-utils-git" "zfs-utils-lts" "zfs-utils" "zfs-utils-common-git" "zfs-utils-common")
install=zfs-utils.install
backup=('etc/zfs/zed.d/zed.rc' 'etc/default/zfs')
cd "${srcdir}/zfs"
make DESTDIR="${pkgdir}" install
# Remove uneeded files
rm -r "${pkgdir}"/etc/init.d
rm -r "${pkgdir}"/usr/lib/dracut
# Autoload the zfs module at boot
mkdir -p "${pkgdir}/etc/modules-load.d"
printf "%s\n" "zfs" > "${pkgdir}/etc/modules-load.d/zfs.conf"
# fix permissions
chmod 750 ${pkgdir}/etc/sudoers.d
# Install the support files
install -D -m644 "${srcdir}"/zfs-utils.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
install -D -m644 "${srcdir}"/zfs-utils.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
install -D -m644 "${srcdir}"/zfs-utils.bash-completion-r1 "${pkgdir}"/usr/share/bash-completion/completions/zfs
}
|