blob: 314f7852ba6746c7671244397aaf35a10e8e3ed8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Kaizhao Zhang <zhangkaizhao@gmail.com>
libyaml_version=0.2.5
pkgname=zigmod
pkgver=45
pkgrel=1
pkgdesc="A package manager for the Zig programming language"
url="https://github.com/nektro/zigmod"
license=('MIT')
makedepends=('git' 'zig')
arch=('x86_64')
source=(
"${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
"https://github.com/yaml/libyaml/releases/download/${libyaml_version}/yaml-${libyaml_version}.tar.gz"
)
sha256sums=(
'2e5525a566a90883dd869fd769290efd4de0e932498e34d5cd02cde40e9fb5a3'
'c642ae9b75fee120b2d96c712538bd2cf283228d2337df2cf2988e3c02678ef4'
)
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
rm -r libs/yaml
ln -s "${srcdir}/yaml-${libyaml_version}" libs/yaml
zig build -Dbootstrap
./zig-out/bin/zigmod fetch
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
zig build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -D -m755 zig-out/bin/zigmod "${pkgdir}/usr/bin/zigmod"
install -D -m644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
cp -r docs "${pkgdir}/usr/share/doc/${pkgname}/docs"
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|