summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1dfe5fba3bd6a2c3c902c934004dde3adcb04532 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=zlib-git
pkgver=1.2.11.r27.g4346a16
pkgrel=1
pkgdesc="A massively spiffy yet delicately unobtrusive compression library (git develop branch)"
arch=('i686' 'x86_64')
url="https://www.zlib.net/"
license=('ZLIB')
depends=('glibc')
makedepends=('git')
provides=('zlib')
conflicts=('zlib')
options=('staticlibs')
source=("git+https://github.com/madler/zlib.git#branch=develop")
sha256sums=('SKIP')


pkgver() {
  cd "zlib"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "zlib"

  ./configure --prefix="/usr"
  make
}

check() {
  cd "zlib"

  make test
}

package() {
  cd "zlib"

  make DESTDIR="$pkgdir" install

  sed -n '/Copyright (C) 1995-/,/madler@alumni.caltech.edu/p' "zlib.h" > "_LICENSE"
  install -Dm644 "_LICENSE" "$pkgdir/usr/share/licenses/zlib/LICENSE"
}