blob: 896c6e2d0722ade3127aba289486d630dc3db91d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Jacek Szafarkiewicz <szafar at linux dot pl>
pkgname=zlib-ng
pkgver=2.0.6
pkgrel=2
pkgdesc="zlib replacement with optimizations for 'next generation' systems"
arch=('i686' 'x86_64')
url="https://github.com/zlib-ng/zlib-ng"
license=('custom:zlib')
depends=('glibc')
makedepends=('cmake')
options=('staticlibs')
source=("$pkgname-$pkgver-src.tar.gz::https://github.com/zlib-ng/zlib-ng/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('8258b75a72303b661a238047cb348203d88d9dddf85d480ed885f375916fcab6')
build() {
cd "$pkgname-$pkgver"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
./
make -C "_build"
}
check() {
cd "$pkgname-$pkgver"
make -C "_build" test
}
package() {
cd "$pkgname-$pkgver"
make -C "_build" DESTDIR="$pkgdir" install
install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/zlib-ng"
}
|