blob: 1967a32957af1dda0c7dbc7274ecc17e1a0d0935 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Jacek Szafarkiewicz <szafar at linux dot pl>
pkgname=zlib-ng
pkgver=2.1.2
pkgrel=1
pkgdesc="zlib replacement with optimizations for 'next generation' systems"
arch=('i686' 'x86_64')
url="https://github.com/zlib-ng/zlib-ng"
license=('custom:zlib')
depends=('glibc')
makedepends=('cmake')
options=('staticlibs')
source=("$pkgname-$pkgver-src.tar.gz::https://github.com/zlib-ng/zlib-ng/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('383560d6b00697c04e8878e26c0187b480971a8bce90ffd26a5a7b0f7ecf1a33')
build() {
cd "$pkgname-$pkgver"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
./
make -C "_build"
}
check() {
cd "$pkgname-$pkgver"
make -C "_build" test
}
package() {
cd "$pkgname-$pkgver"
make -C "_build" DESTDIR="$pkgdir" install
install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/zlib-ng"
}
|